# Maintainer: Phillip Smith <fukawi2@NO-SPAM.archserver.org>
# Contributor: Allan McRae <allan@archlinux.org>

pkgname=abs
pkgver=2.3.3
pkgrel=4
pkgdesc="Utilities to download and work with the Arch Build System (ABS)"
arch=('any')
url="http://projects.archlinux.org/git/?p=abs.git"
license=('GPL')
depends=('bash' 'rsync')
backup=('etc/abs.conf')
install="$pkgname.install"
source=("ftp://repo.archserver.org/other/abs/${pkgname}-${pkgver}.tar.gz"
        "archserver.patch"
        "abs.conf")
md5sums=('a65e55d96118532e1138ff107ac7f489'
         'cd63b2fbf96b3ed96ed36fd0d66cebc9'
         'fab49881810509cd35f7987b8de0c87e')

build() {
  cd $srcdir/$pkgname
  
  patch < $srcdir/archserver.patch || return 1

  make CONFDIR=/etc/ || return 1
}

package() {
  cd $srcdir/$pkgname
  
  make CONFDIR=/etc/ DESTDIR=${pkgdir} install || return 1

  # Put in ArchServer config file
  rm -f $pkgdir/etc/$pkgname.conf || return 1
  install -m644 $srcdir/$pkgname.conf $pkgdir/etc/$pkgname.conf || return 1
  
  # Add readme file, and make base /var/abs path
  install -dm755 ${pkgdir}/var/abs/local/
  install -Dm644 ${srcdir}/abs/README ${pkgdir}/var/abs/README
  
  # cleanup stuff we don't need
  rm -Rf $pkgdir/usr/share/
}

# vim:set ts=2 sw=2 et:
