# Contributor: Phillip Smith <fukawi2@NOSPAM.gmail.com>

pkgname=apache-mod_bw
_realname=mod_bw
pkgver=0.7
pkgrel=1
pkgdesc="DSO module for Apache that throttles HTTP traffic"
url="http://bwmod.sourceforge.net"
arch=('i686' 'x86_64')
license=('apache')
depends=('apache')
makedepends=('apache')
install="$pkgname.install"
source=("http://bwmod.sourceforge.net/files/$_realname-$pkgver.tgz"
        'apr_atomic_fix.patch')
md5sums=('d792a892517ca89f21ac2a6c01e6ccb2'
         'f9cdca58c58678a2e334086ccf81f898')

_MODDIR='usr/lib/httpd/modules'
_DOCDIR="usr/share/doc/$pkgname"

build() {  
  cd $srcdir/$_realname

  # fix for undefined symbol errors:
  # http://4j.blogspot.com/2008/09/fix-for-modbw-when-getting-error.html
  patch < $srcdir/apr_atomic_fix.patch
  
  # make the module
  /usr/sbin/apxs -c -o $_realname.so $_realname.c
}

package() {
  cd $srcdir/$_realname

  install -Dm644 .libs/$_realname.so $pkgdir/$_MODDIR/$_realname.so
  install -Dm644 $_realname.txt $pkgdir/$_DOCDIR/$pkgname.txt
}

# vim:set ts=2 sw=2 et:
