# Maintainer: Phillip Smith <fukawi2@NOSPAM.gmail.com>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>

pkgname=apache
pkgver=2.2.15
pkgrel=1
pkgdesc='A high performance Unix-based HTTP server'
arch=('i686' 'x86_64')
groups=('lamp' 'lapp')
options=('!libtool')
url='http://www.apache.org/dist/httpd'
license=('APACHE')
backup=('etc/httpd/conf/httpd.conf'
        'etc/httpd/conf/extra/httpd-{autoindex,dav,default,info,languages}.conf'
        'etc/httpd/conf/extra/httpd-{manual,mpm,multilang-errordoc}.conf'
        'etc/httpd/conf/extra/httpd-{ssl,userdir,vhosts}.conf'
        'etc/logrotate.d/httpd')
depends=('openssl' 'zlib' 'apr-util' 'pcre')
optdepends=('lynx: apachectl status')
source=("http://www.apache.org/dist/httpd/httpd-${pkgver}.tar.bz2"
        'httpd.logrotate'
        'rc.httpd'
        'arch.layout'
        'noscriptkiddies.conf')
md5sums=('016cec97337eccead2aad6a7c27f2e14'
         'f4d627c64024c1b7b95efb5ffbaa625e'
         'bddd84dafa770d74df1dc1f96bd71823'
         '3d659d41276ba3bfcb20c231eb254e0c'
         'b83d3c511a123f0506b9feb9c583c657')

build() {
	cd $srcdir/httpd-${pkgver}

	# set default user
	sed -e 's#User daemon#User http#' \
	    -e 's#Group daemon#Group http#' \
	    -i docs/conf/httpd.conf.in || return 1
  
  # Configure
	cat ${srcdir}/arch.layout >> config.layout
	./configure \
    --enable-layout=Arch \
		--enable-modules=all \
		--enable-mods-shared=all \
		--enable-so \
		--enable-suexec \
		--with-suexec-caller=http \
		--with-suexec-docroot=/srv/http \
		--with-suexec-logfile=/var/log/httpd/suexec.log \
		--with-suexec-bin=/usr/sbin/suexec \
		--with-suexec-uidmin=99 --with-suexec-gidmin=99 \
		--enable-ldap --enable-authnz-ldap \
		--enable-cache --enable-disk-cache --enable-mem-cache --enable-file-cache \
		--enable-ssl --with-ssl \
		--enable-deflate --enable-cgid \
		--enable-proxy --enable-proxy-connect \
		--enable-proxy-http --enable-proxy-ftp \
		--enable-dbd \
		--with-apr=/usr/bin/apr-1-config \
		--with-apr-util=/usr/bin/apu-1-config \
		--with-pcre=/usr || return 1

	make || return 1
}

package() {
	cd $srcdir/httpd-${pkgver}
  
  # install main package
	make DESTDIR=${pkgdir} install || return 1

  # install rc script
	install -D -m755 ${srcdir}/rc.httpd ${pkgdir}/etc/rc.d/httpd || return 1

  # install logrotate scriptlets
	install -D -m644 ${srcdir}/httpd.logrotate ${pkgdir}/etc/logrotate.d/httpd || return 1
  
	# symlinks for /etc/httpd
	ln -fs /var/log/httpd ${pkgdir}/etc/httpd/logs || return 1
	ln -fs /var/run/httpd ${pkgdir}/etc/httpd/run || return 1
	ln -fs /usr/lib/httpd/modules ${pkgdir}/etc/httpd/modules || return 1
	ln -fs /usr/lib/httpd/build ${pkgdir}/etc/httpd/build || return 1
  
	# set sane defaults
	sed -e 's#/usr/lib/httpd/modules/#modules/#' \
	    -e 's|#\(Include conf/extra/httpd-multilang-errordoc.conf\)|\1|' \
	    -e 's|#\(Include conf/extra/httpd-autoindex.conf\)|\1|' \
	    -e 's|#\(Include conf/extra/httpd-languages.conf\)|\1|' \
	    -e 's|#\(Include conf/extra/httpd-userdir.conf\)|\1|' \
	    -e 's|#\(Include conf/extra/httpd-default.conf\)|\1|' \
	    -i ${pkgdir}/etc/httpd/conf/httpd.conf || return 1
  
	# cleanup
	rm -rf ${pkgdir}/usr/share/httpd/manual || return 1
	rm -rf ${pkgdir}/etc/httpd/conf/original || return 1
	rm -rf ${pkgdir}/srv/http || return 1
	rmdir ${pkgdir}/usr/bin || return 1
}

# vim:set ts=2 sw=2 et:
