# Maintainer: Markus M. May <triplem@tu.archserver.org>

# Contributor: Phillip Smith <fukawi2@NOSPAM.gmail.com>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>

pkgname=apache
pkgver=2.2.19
pkgrel=1
pkgdesc='A high performance Unix-based HTTP server'
arch=('i686' 'x86_64')
groups=('lamp' 'lapp')
options=('!libtool')
url='http://www.apache.org/dist/httpd'
license=('APACHE')
backup=('etc/httpd/conf/httpd.conf'
        'etc/httpd/conf/extra/httpd-{autoindex,dav,default,info,languages}.conf'
        'etc/httpd/conf/extra/httpd-{manual,mpm,multilang-errordoc}.conf'
        'etc/httpd/conf/extra/httpd-{ssl,userdir,vhosts}.conf'
        'etc/logrotate.d/httpd')
depends=('openssl' 'zlib' 'apr-util' 'pcre')
optdepends=('lynx: apachectl status')
source=("http://www.apache.org/dist/httpd/httpd-${pkgver}.tar.bz2"
        'httpd.logrotate' 'rc.httpd' 'arch.layout' 'noscriptkiddies.conf')
md5sums=('832f96a6ec4b8fc7cf49b9efd4e89060'
         '12f3d7c1abac0ed6730f12dea0b2ed1b'
         'bddd84dafa770d74df1dc1f96bd71823'
         '3d659d41276ba3bfcb20c231eb254e0c'
         'b83d3c511a123f0506b9feb9c583c657')

build() {
	cd $srcdir/httpd-${pkgver}

	# set default user
	sed -e 's#User daemon#User http#' \
	    -e 's#Group daemon#Group http#' \
	    -i docs/conf/httpd.conf.in
  
  # Configure
	cat ${srcdir}/arch.layout >> config.layout
	./configure \
    --enable-layout=Arch \
		--enable-modules=all \
		--enable-mods-shared=all \
		--enable-so \
		--enable-suexec \
		--with-suexec-caller=http \
		--with-suexec-docroot=/srv/http \
		--with-suexec-logfile=/var/log/httpd/suexec.log \
		--with-suexec-bin=/usr/sbin/suexec \
		--with-suexec-uidmin=99 --with-suexec-gidmin=99 \
		--enable-ldap --enable-authnz-ldap \
		--enable-cache --enable-disk-cache --enable-mem-cache --enable-file-cache \
		--enable-ssl --with-ssl \
		--enable-deflate --enable-cgid \
		--enable-proxy --enable-proxy-connect \
		--enable-proxy-http --enable-proxy-ftp \
		--enable-dbd \
		--with-apr=/usr/bin/apr-1-config \
		--with-apr-util=/usr/bin/apu-1-config \
		--with-pcre=/usr

	make
}

package() {
	cd $srcdir/httpd-${pkgver}
  
  # install main package
	make DESTDIR=${pkgdir} install

  # install rc script
	install -D -m755 ${srcdir}/rc.httpd ${pkgdir}/etc/rc.d/httpd

  # install logrotate scriptlets
	install -D -m644 ${srcdir}/httpd.logrotate ${pkgdir}/etc/logrotate.d/httpd
  
	# symlinks for /etc/httpd
	ln -fs /var/log/httpd ${pkgdir}/etc/httpd/logs
	ln -fs /var/run/httpd ${pkgdir}/etc/httpd/run
	ln -fs /usr/lib/httpd/modules ${pkgdir}/etc/httpd/modules
	ln -fs /usr/lib/httpd/build ${pkgdir}/etc/httpd/build
  
	# set sane defaults
  # - Disable all proxy modules to avoid accidental open proxies
	sed -e 's#/usr/lib/httpd/modules/#modules/#' \
	    -e 's|#\(Include conf/extra/httpd-multilang-errordoc.conf\)|\1|' \
	    -e 's|#\(Include conf/extra/httpd-autoindex.conf\)|\1|' \
	    -e 's|#\(Include conf/extra/httpd-languages.conf\)|\1|' \
	    -e 's|#\(Include conf/extra/httpd-userdir.conf\)|\1|' \
	    -e 's|#\(Include conf/extra/httpd-default.conf\)|\1|' \
      -e '/^LoadModule proxy_/ s/^/#/' \
	    -i ${pkgdir}/etc/httpd/conf/httpd.conf
  
	# cleanup
	rm -rf ${pkgdir}/usr/share/httpd/manual
	rm -rf ${pkgdir}/etc/httpd/conf/original
	rm -rf ${pkgdir}/srv/http
	rmdir ${pkgdir}/usr/bin
}

# vim:set ts=2 sw=2 et:
