# Maintainer: Thomas Bächler <thomas@archlinux.org>
pkgname=attr
pkgver=2.4.44
pkgrel=2
pkgdesc="Extended attribute support library for ACL support"
arch=('i686' 'x86_64')
url="http://oss.sgi.com/projects/xfs/"
license=('LGPL')
groups=('base')
depends=('glibc') 
makedepends=('gettext' 'autoconf')
replaces=('xfsattr')
provides=('xfsattr')
conflicts=('xfsattr')
options=('!libtool')
source=("ftp://ftp.archlinux.org/other/attr/attr-${pkgver}.src.tar.gz")
md5sums=('adeefe65c5ad1febe46da185c5bfd5d4')

build() {
  cd $srcdir/attr-$pkgver 
  
  autoconf || return 1
  
  ./configure --prefix=/usr || return 1
  
  sed -i -e 's/man2//g' man/Makefile || return 1
  
  make || return 1
}

package() {
  cd $srcdir/attr-$pkgver || return 1
  
  make prefix=$pkgdir/usr install install-lib install-dev || return 1

  # tidy up
  cd $pkgdir || return 1

  mkdir -v lib || return 1
  mv -v usr/lib/libattr.so* lib/ || return 1
  ln -sv ../../lib/libattr.so.1 usr/lib/libattr.so || return 1

  mv -v usr/libexec/libattr.{a,la} usr/lib/ || return 1
  rm -rvf usr/libexec || return 1
}

# vim:set ts=2 sw=2 et:
