# Maintainer: Aaron Griffin <aaron@archlinux.org>

pkgname=bash
_patchlevel=033 #prepare for some patches
pkgver=4.0.$_patchlevel
pkgrel=2
pkgdesc="The GNU Bourne Again shell"
arch=('i686' 'x86_64')
license=('GPL')
url="http://www.gnu.org/software/bash/bash.html"
groups=('base')
backup=(etc/profile.bash etc/skel/.bashrc etc/skel/.bash_profile)
depends=('readline>=6.0' 'glibc')
makedepends=(gzip)
provides=('sh')
install=bash.install
source=("http://ftp.gnu.org/gnu/$pkgname/$pkgname-4.0.tar.gz"
        'profile.bash'
        'bashrc'
        'enable-system-config-files.patch'
        'system.bashrc')
if [ $_patchlevel -gt 000 ]; then
    for p in $(seq -w 001 $_patchlevel); do
        source=(${source[@]} "http://ftp.gnu.org/gnu/bash/bash-4.0-patches/bash40-$p")
    done
fi
md5sums=('a90a1b5a6db4838483f05438e05e8eb9'
         'c2fae355facefcac8a732cce877da194'
         '3d2837e84645eac9bde399b58014bafa'
         '51725defa4c2dec49c1bc15883e0bee2'
         '196697769f1667a8a1aed608811129c6'
         'bc7f4762443939bd7dccb42370f0d932'
         'c2a4a4786a83ed4ec366c6a8924369a2'
         '22e8a824eddba21a8fce10d7984c2aba'
         'ed7cbced8c7c964323265522369a37a2'
         '8ed86b7d31423d71ecf3148251d63512'
         '5f447338cb98ff156cabf1fd9879d5f3'
         '96e946cb66a4ca186cba1da44f1ee163'
         'd3eb7b6f00d525e032478c33f51d46a8'
         '340601c997ce569532417a7ae92248b8'
         '0bd5ab96d514ffb1afbb8c7984b15146'
         '32cb20f339a20e1e9fb37a5d18f18fca'
         '33fd9e93d30a17988c19554ef26d56e0'
         'a266b42df5e9ed7e8818a8b00d50e00b'
         '86cac78f191a32cd1404f11264eb9b2a'
         'bb41963d030bc61a20e8185367b337c5'
         'f75455048a086528971252fd979b8755'
         '34b2cd57271a452f4a26b39d77ff908f'
         '99318eed8dcc05e10a14ae27043f175d'
         'af3b9aaeadc71a5007bec2b98c751cde'
         'eb7c7ddeb7e8451eb59228dca3329696'
         '585d701b978ceb63967dc020db3a2234'
         '7a70f2608f90f6ac0c2051e5f1c6c414'
         '7a23aa41630dd4fe8d30108a200e2d96'
         '82ba5fc9eb780eb57d8b7628a17b7d74'
         'b26f9007ac4eef5c378f1abcb8959025'
         '83bc844c82d0a30740e8d91a8238bfa9'
         'a41c187f05ecab07389c18acc91214c6'
         'fcc367e6471267d2e397257e703b817d'
         '4d4da1c0be8dfee8e2a6a7703901130f'
         '55cbdc8e5173d7d59bf1113c3ff590dc'
         '389635281133416de9d13295251cabc7'
         'd646cb4aed8e0f0d1d47eea2ed5f3690'
         'd3e77d2a0a051478aca8c30d13ded834')

build() {
  cd ${srcdir}/${pkgname}-4.0
  
  for p in ../bash40-*; do
    [ -e "$p" ] || continue
    msg "applying patch ${p}"
    patch -Np0 -i ${p} || return 1
  done
  
  patch -Np0 -i ../enable-system-config-files.patch || return 1
  
  ./configure \
    --prefix=/usr \
    --with-curses \
    --enable-readline \
    --without-bash-malloc \
    --with-installed-readline \
    --bindir=/bin \
    --mandir=/usr/share/man \
    --infodir=/usr/share/info || return 1
  make || return 1
}

package() {
  cd ${srcdir}/${pkgname}-4.0
  
  make DESTDIR=${pkgdir} install
  
  install -Dm644 ${srcdir}/profile.bash ${pkgdir}/etc/profile.bash || return 1
  install -Dm644 ${srcdir}/system.bashrc ${pkgdir}/etc/bash.bashrc || return 1
  
  # for now, bash is our default /bin/sh
  cd ${pkgdir}/bin
  ln -s bash sh
  
  mkdir -p ${pkgdir}/etc/skel/
  install -Dm644 ${srcdir}/bashrc ${pkgdir}/etc/skel/.bashrc
  echo 'source $HOME/.bashrc' >${pkgdir}/etc/skel/.bash_profile
}

# vim:set ts=2 sw=2 et:
