# Maintainer: Markus M. May <triplem@tu.archserver.org>

# Contributor: Samed Beyribey <ras0ir@tu.archserver.org>
# Contributor: Phillip Smith <fukawi2@archserver.org>
# Contributor: judd <jvinet@zeroflux.org>
# Contributor: Mario Vazquez <mario_vazq@hotmail.com>

pkgname=bind
# Use a period and not a hyphen before the patch level for proper versioning.
pkgver=9.7.3.P3
_pkgver=9.7.3-P3
pkgrel=2
pkgdesc="Berkeley Internet Name Domain, aka named DNS server"
arch=('i686' 'x86_64')
url="http://www.isc.org/index.pl?/sw/bind/"
license=('custom:ISC')
backup=('etc/named.conf' 'etc/logrotate.d/named' 'etc/conf.d/named' 'etc/cron.d/named-fetchroots')
depends=('openssl')
provides=('dns-server')
options=('!libtool')
install=bind.install
source=("ftp://ftp.isc.org/isc/bind9/${_pkgver}/${pkgname}-${_pkgver}.tar.gz"
        "named.root-$pkgver-$pkgrel::ftp://ftp.rs.internic.net/domain/named.root"
        'named.conf' 'localhost.zone' '127.0.0.zone' 'rc.named' 'confd.named'
        'named.logrotate' 'bind.so_bsdcompat.patch' 'notools.patch' 'fetchroots.sh')
md5sums=('f7ea260a90b3c835116aae37ac3e1596' 'd7a1cb305b7b5b72df4e574777f76723'
         'e503fa88accbfeb4aae8a9bd7d332ba5' 'ab5beef0b41eb6376c7f1f4ee233172b'
         'bdbdfe4990b0903984306dd14f98b951' '750f283c7774ffe75cd215bce46b03cd'
         '475fde63600d7d95980de991f02d6b6d' '0cd759a4f166fce5bb4ecd5eec15d3cc'
         '447d58721cfee0e1e377b46f7d50b327' 'e7f3c5c54f18c86f6716700e82f7e9fd'
         '86c18036dc05982b77c54c4ace997025')

build() {
  export MAKEFLAGS="-j1"
  
  cd $srcdir/${pkgname}-${_pkgver}
  
  patch -Np0 -i $srcdir/bind.so_bsdcompat.patch
  patch -Np1 -i $srcdir/notools.patch

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --with-libtool \
    --enable-shared \
    --disable-threads \
    --with-openssl=yes \
    --disable-linux-caps \
    --without-libxml2

  make
}

package() {
  cd $srcdir/${pkgname}-${_pkgver}

  make DESTDIR=$pkgdir install

  # install config file
  install -Dm640 $srcdir/named.conf $pkgdir/etc/named.conf
  
  # install default localhost zones
  install -Dm600 $srcdir/127.0.0.zone $pkgdir/srv/named/127.0.0.zone
  install -Dm600 $srcdir/localhost.zone $pkgdir/srv/named/localhost.zone
  
  # install fetchroots.sh script
  install -Dm744 $srcdir/fetchroots.sh $pkgdir/usr/bin/fetchroots
  mkdir -p $pkgdir/etc/cron.d
  echo "23 40 * * sun   named   /usr/bin/fetchroots" > $pkgdir/etc/cron.d/named-fetchroots
  
  # install root.hint file
  install -Dm600 $srcdir/named.root-$pkgver-$pkgrel $pkgdir/srv/named/named.root-$pkgver-$pkgrel
  ln -sf named.root-$pkgver-$pkgrel $pkgdir/srv/named/root.hint
  
  # install logrototate script
  install -Dm600 $srcdir/named.logrotate $pkgdir/etc/logrotate.d/named
  
  # install rc init script and conf file
  install -Dm755 $srcdir/rc.named $pkgdir/etc/rc.d/named
  install -Dm644 $srcdir/confd.named $pkgdir/etc/conf.d/named
  
  # create runtime dir
  install -dm755 $pkgdir/var/run/named

  # install the licence file
  install -Dm644 COPYRIGHT $pkgdir/usr/share/licenses/$pkgname/LICENSE
  
  # fix permissions
  chmod 700 $pkgdir/srv/named
  chown root:40 $pkgdir/etc/named.conf
  chown -R 40:40 $pkgdir/srv/named
  chown 40:40 $pkgdir/var/run/named
}

# vim:set ts=2 sw=2 et:
