# Maintainer: Allan McRae <allan@archlinux.org>
# Contributor: judd <jvinet@zeroflux.org>

pkgname=coreutils
pkgver=7.6
pkgrel=2
pkgdesc="The basic file, shell and text manipulation utilities of the GNU operating system"
arch=('i686' 'x86_64')
license=('GPL3')
url="http://www.gnu.org/software/coreutils"
groups=('base')
depends=('glibc' 'shadow' 'pam' 'acl' 'gmp' 'libcap')
provides=('mktemp')
conflicts=('mktemp')
replaces=('sh-utils' 'fileutils' 'textutils' 'mktemp')
backup=('etc/pam.d/su')
install="${pkgname}.install"
options=('!emptydirs' '!makeflags')
source=("ftp://ftp.gnu.org/gnu/$pkgname/$pkgname-$pkgver.tar.gz"
      	'coreutils-i18n.patch'
      	'coreutils-uname.patch'
      	'coreutils-pam.patch'
      	'coreutils-6.10-configuration.patch'
    	  'pam.su')
md5sums=('3d82f979229365f880da750642e67cf3'
         '8a93fa488e9329a8174085aa023d0d54'
         'f743664abbc82cc93f39b6c2fefe8936'
         '72aa92f24ff078d1c7b6d2d92a1075b5'
         '9f1e0859009814970c5893bbc6d66e2e'
         'fa85e5cce5d723275b14365ba71a8aad')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}

  # added pam patch and i18n patch from fedora cvs
  patch -Np1 -i $srcdir/coreutils-pam.patch || return 1
  patch -Np1 -i $srcdir/coreutils-i18n.patch || return 1
  patch -Np1 -i $srcdir/coreutils-6.10-configuration.patch || return 1

  # from gentoo portage
  patch -Np1 -i $srcdir/coreutils-uname.patch || return 1

  autoreconf -v
  ./configure \
    --prefix=/usr \
    --enable-install-program=su \
    --enable-pam ac_cv_func_openat=no || return 1
  make || return 1
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  
  make DESTDIR=${pkgdir} install || return 1
  
  rm -f ${pkgdir}/usr/bin/hostname ${pkgdir}/usr/share/man/man1/hostname.1 || return 1
  rm -f ${pkgdir}/usr/bin/uptime ${pkgdir}/usr/share/man/man1/uptime.1 || return 1
  rm -f ${pkgdir}/usr/bin/groups ${pkgdir}/usr/share/man/man1/groups.1 || return 1
  rm -f ${pkgdir}/usr/bin/kill ${pkgdir}/usr/share/man/man1/kill.1 || return 1
  
  cd ${pkgdir}/usr/bin || return 1
  install -dm755 ${pkgdir}/{bin,sbin,usr/sbin} || return 1
  mv su date echo false pwd stty true uname cat tr cut readlink $pkgdir/bin || return 1
  mv dd cp df du ln ls mv rm dir sync vdir chgrp chmod chown $pkgdir/bin || return 1
  mv mkdir mknod rmdir shred touch mkfifo dircolors install sleep $pkgdir/bin || return 1
  mv chroot $pkgdir/usr/sbin || return 1
  ln -sf test [ || return 1
  ln -sf /bin/sleep ${pkgdir}/usr/bin/sleep || return 1
  install -Dm644 $srcdir/pam.su ${pkgdir}/etc/pam.d/su || return 1
  
  ls -lha ${pkgdir}/bin/su
  chmod -v 4555 ${pkgdir}/bin/su || return 1
}
# vim:set ts=2 sw=2 et:
