pkgname=dmraid
pkgver=1.0.0.rc15
pkgrel=2
pkgdesc="Device mapper RAID interface"
url="http://people.redhat.com/~heinzm/sw/dmraid/"
depends=('device-mapper>=2.0.54')
arch=('i686' 'x86_64')
license=('GPL')
install="dmraid.install"
#source=("http://people.redhat.com/~heinzm/sw/dmraid/src/$pkgname-$pkgver.tar.bz2"
source=("http://people.redhat.com/~heinzm/sw/dmraid/src/old/$pkgname-$pkgver.tar.bz2"
        'dmraid_install'
        'dmraid_hook')
md5sums=('2602887205a35f89b59eeba3a868150f'
         'db9a72cbf07560059d407c874f646240'
         'afdb3cd655ea0145410e2aae247c7bcf')

build() {
  cd $srcdir/$pkgname/$pkgver
  
  # create static bin
  ./configure --enable-static_link --prefix=/usr || return 1
  make || return 1
}

package() {
  cd $srcdir/$pkgname/$pkgver
  
  make DESTDIR=$pkgdir exec_prefix=$pkgdir/usr install || return 1
  mv $pkgdir/usr/sbin/dmraid $pkgdir/usr/sbin/dmraid.static || return 1

  # create dynamic linked bin
  ./configure --prefix=/usr || return 1
  make || return 1
  make DESTDIR=$pkgdir exec_prefix=$pkgdir/usr install || return 1
  mkdir -p $pkgdir/var/lock/dmraid || return 1
  chmod 1777 $pkgdir/var/lock/ || return 1
  install -D -m644 $srcdir/dmraid_install $pkgdir/lib/initcpio/install/dmraid || return 1
  install -D -m644 $srcdir/dmraid_hook $pkgdir/lib/initcpio/hooks/dmraid || return 1
  # fix .a file
  chmod 644 $pkgdir/usr/lib/libdmraid.a || return 1
}

# vim:set ts=2 sw=2 et:
