# Maintainer: Dan McGee <dan@archlinux.org>

pkgname=git
pkgver=1.6.5.1
pkgrel=1
pkgdesc="the fast distributed version control system"
arch=(i686 x86_64)
url="http://git-scm.com/"
license=('GPL2')
depends=('curl' 'expat>=2.0' 'perl-error' 'perl>=5.10.0')
optdepends=('tk: gitk and git gui'
            'perl-libwww: git svn'
            'perl-term-readkey: git svn'
            'subversion: git svn'
            'cvsps: git cvsimport')
replaces=('git-core')
provides=('git-core')
source=("http://kernel.org/pub/software/scm/git/${pkgname}-${pkgver}.tar.bz2"
        "http://kernel.org/pub/software/scm/git/git-manpages-${pkgver}.tar.bz2")
md5sums=('fd784f407d538705ed36c0498542d4f5'
         'a0e59428400e615904093af3a5c9495e')

build() {
  cd $srcdir/$pkgname-$pkgver
  
  make prefix=/usr gitexecdir=/usr/lib/git-core || return 1
}

package() {
  cd $srcdir/$pkgname-$pkgver
  
  make prefix=/usr gitexecdir=/usr/lib/git-core \
    NO_CROSS_DIRECTORY_HARDLINKS=1 \
    INSTALLDIRS=vendor DESTDIR=${pkgdir} install || return 1
  
  # bash completion
  mkdir -p $pkgdir/etc/bash_completion.d/ || return 1
  install -m644 ./contrib/completion/git-completion.bash $pkgdir/etc/bash_completion.d/git || return 1
  
  # contrib stuff
  cp -a ./contrib $pkgdir/usr/share/ || return 1
  
  # install man pages
  for mansect in man1 man5 man7 ; do
    for manpage in $srcdir/$mansect/* ; do
      install -D -m644 $manpage $pkgdir/usr/share/man/$mansect/$(basename $manpage) || return 1
    done
  done
  
  # remove perllocal.pod, .packlist, and empty directories.
  rm -rf $pkgdir/usr/lib/perl5 || return 1
}

# vim:set ts=2 sw=2 et:
