# Maintainer: Markus M. May <triplem@tu.archserver.org>
# Contributor: Dan McGee <dan@archlinux.org>

pkgname=git
pkgver=1.7.3.4
pkgrel=1
pkgdesc="the fast distributed version control system"
arch=(i686 x86_64)
url="http://git-scm.com/"
license=('GPL2')
depends=('curl' 'expat>=2.0' 'perl-error' 'perl>=5.10.0')
optdepends=('tk: gitk and git gui'
            'perl-libwww: git svn'
            'perl-term-readkey: git svn'
            'perl-net-smtp-ssl: git send-email TLS support'            
            'subversion: git svn'
            'python2: various helper scripts'
            'cvsps: git cvsimport')
makedepends=('python')            
replaces=('git-core')
provides=('git-core')
source=("http://kernel.org/pub/software/scm/git/${pkgname}-${pkgver}.tar.bz2"
        "http://kernel.org/pub/software/scm/git/git-manpages-${pkgver}.tar.bz2"
        git-daemon
        git-daemon.conf)
md5sums=('3a2602016f98c529cda7b9fad1a6e216'
         'ec0883134fa00628d9057d1551d9c739'
         'd777ff1a239b3d810dcf5d89f9d894af'
         '9d065134210aa0dd3f2b40d12d915040')

build() {
	export PYTHON_PATH='/usr/bin/python'
  cd $srcdir/$pkgname-$pkgver
  
  make prefix=/usr gitexecdir=/usr/lib/git-core || return 1
}

package() {
	export PYTHON_PATH='/usr/bin/python'	
  cd $srcdir/$pkgname-$pkgver
  
  make prefix=/usr gitexecdir=/usr/lib/git-core \
    NO_CROSS_DIRECTORY_HARDLINKS=1 \
    INSTALLDIRS=vendor DESTDIR=${pkgdir} install || return 1
  
  # bash completion
  mkdir -p $pkgdir/etc/bash_completion.d/ || return 1
  install -m644 ./contrib/completion/git-completion.bash $pkgdir/etc/bash_completion.d/git || return 1
  
  # emacs interface
  mkdir -p $pkgdir/usr/share/emacs/site-lisp
  mv ./contrib/emacs/ $pkgdir/usr/share/emacs/site-lisp/git
  rm $pkgdir/usr/share/emacs/site-lisp/git/.gitignore  

  # contrib stuff
  cp -a ./contrib $pkgdir/usr/share/ || return 1
    
  # install man pages
  for mansect in man1 man5 man7 ; do
    for manpage in $srcdir/$mansect/* ; do
      install -D -m644 $manpage $pkgdir/usr/share/man/$mansect/$(basename $manpage) || return 1
    done
  done
  
  # remove perllocal.pod, .packlist, and empty directories.
  rm -rf $pkgdir/usr/lib/perl5 || return 1
  
  # git daemon script
  install -D -m755 $srcdir/git-daemon $pkgdir/etc/rc.d/git-daemon
  install -D -m644 $srcdir/git-daemon.conf $pkgdir/etc/conf.d/git-daemon.conf  
}

# vim:set ts=2 sw=2 et:
