# Maintainer: Phillip Smith <fukawi2@archserver.org>
# Maintainer: Thomas Baechler <thomas@archlinux.org>
# Maintainer: Aaron Griffin <aaron@archlinux.org>

pkgname=initscripts
pkgver=2009.08
pkgrel=4
pkgdesc="System initialization/bootup scripts"
arch=('i686' ' x86_64')
url="http://www.archlinux.org"
license=('GPL')
groups=('base')
backup=('etc/inittab' 'etc/rc.conf' 'etc/rc.local' 'etc/rc.local.shutdown')
depends=('glibc' 'bash' 'awk' 'grep' 'coreutils' 'sed' 'udev>=139-1' 'net-tools' 'ncurses' 'kbd' 'findutils' 'sysvinit')
optdepends=('bridge-utils: Network bridging support'
            'dhcpcd: DHCP network configuration'
            'wireless_tools: Wireless networking')
install=initscripts.install
source=("ftp://ftp.archlinux.org/other/initscripts/${pkgname}-${pkgver}-1.tar.gz")
md5sums=('b22b03d1df6baee93a31d4279b96eedd')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}-1/
  
  gcc $CFLAGS -o minilogd minilogd.c || return 1
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}-1/
  
  sed \
    -e 's|Arch Linux|ArchServer (based on Arch Linux)|g' \
    -e 's|http://www.archlinux.org|http://www.archserver.org|g' \
    -e 's|Copyright 2007-2009 Aaron Griffin|Copyright 2007-2010 Aaron Griffin|g' \
    -i * || return 1
    
  msg "add Phillip"  
  sed -e 's|Copyright 2007-2010 Aaron Griffin"|Copyright 2007-2010 Aaron Griffin"\
printhl "Copyright 2009-2010 Phillip Smith"|g' \
      -i * || return 1
   
  DESTDIR=$pkgdir 
  install -d -m755 ${DESTDIR}/etc/rc.d || return 1
  install -d -m755 ${DESTDIR}/etc/conf.d || return 1
  install -d -m755 ${DESTDIR}/etc/rc.d/functions.d/ || return 1
  install -d -m755 ${DESTDIR}/etc/cron.hourly/ || return 1
  
  for i in inittab rc.conf; do
    install -D -m644 $i ${DESTDIR}/etc/$i || return 1
  done
  for i in rc.local rc.local.shutdown rc.multi rc.shutdown rc.single rc.sysinit; do
    install -D -m755 $i ${DESTDIR}/etc/$i || return 1
  done
  
  install -D -m755 adjtime.cron ${DESTDIR}/etc/cron.hourly/adjtime
  
  install -D -m644 functions ${DESTDIR}/etc/rc.d/functions || return 1
  for i in network netfs; do
    install -D -m755 $i ${DESTDIR}/etc/rc.d/$i || return 1
  done
  
  install -D -m755 minilogd ${DESTDIR}/sbin/minilogd || return 1
}

# vim:set ts=2 sw=2 et:
