# Maintainer: Markus M. May <triplem@tu.archserver.org>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor: Guillaume ALAUX <Guillaume at alaux dot net>
# Contributor: Geoffroy Carrier <geoffroy.carrier@aur.archlinux.org>
# Contributor: Jason Chu <jason@archlinux.org>
pkgname=('jre' 'jdk')
pkgbase=java-sun
pkgver=6u23
pkgrel=1
pkgdesc="Sun/Oracle's implementation of tha Java 6 specification"
arch=('i686' 'x86_64')
        [ "$CARCH" = "i686" ]   && _arch=i586
        [ "$CARCH" = "x86_64" ] && _arch=amd64
url="http://java.sun.com"
license=('custom')
install="jdk.install"
source=("http://download.java.net/dlj/binaries/jdk-${pkgver}-dlj-linux-${_arch}.bin"
			  'construct.sh::http://java.net/projects/jdk-distros/sources/svn/content/trunk/utils/construct.sh?raw=true'
			  'jdk.profile'
			  'jre.profile'
        'derby-network-server'
        'derby-network-server.conf')

[ "${CARCH}" = 'i686' ] && md5sums=('cd02f6e8f46fb4171811150cb820c6ed')
[ "${CARCH}" = 'x86_64' ] && md5sums=('dde0a095412982e6688d6ac425373565')
md5sums+=('94065b612df0046d9ae758943f9f6a75'
          'b83ab5742651b4234b7d2e20785c6693'
          '50b4f5ac4129097461d246645d73a622'
          'a279e195e249000646895d93e199860d'
          '4bdff6982c66d24a879c424aaac3d04d')
					
build() {
  cd ${srcdir}
  mkdir unbundle-jdk
  cd unbundle-jdk
  sh ../jdk-${pkgver}-dlj-linux-${_arch}.bin --accept-license
  cd ..
  sh construct.sh unbundle-jdk linux-jdk linux-jre
}

package_jre() {
  pkgdesc="Sun/Oracle's Java Runtime Environment"
  depends=('glibc' 'libxtst')
  provides=('j2re' 'java-runtime=6')
  conflicts=('j2re' 'java-runtime')
  replaces=('j2re')
  install='jre.install'
 
  cd ${srcdir}

  mkdir -p ${pkgdir}/opt/java
  cp -R linux-jdk/jre ${pkgdir}/opt/java

  install -Dm755 ${srcdir}/jre.profile ${pkgdir}/etc/profile.d/jre.sh

  mkdir -p ${pkgdir}/usr/share/licenses/jre
  cp ${pkgdir}/opt/java/jre/COPYRIGHT ${pkgdir}/usr/share/licenses/jre
  cp ${pkgdir}/opt/java/jre/LICENSE ${pkgdir}/usr/share/licenses/jre
  cp ${pkgdir}/opt/java/jre/THIRDPARTYLICENSEREADME.txt ${pkgdir}/usr/share/licenses/jre
}  

package_jdk() {
  pkgdesc="Sun/Oracle's Java Development Kit"
  depends=('glibc' 'jre')
  provides=('java-environment=6' 'j2sdk')
  conflicts=('java-environment' 'j2sdk')
  replaces=('j2sdk')
  install='jdk.install'

  cd ${srcdir}

  #copy icon
  install -Dm644 ${srcdir}/linux-jdk/jre/lib/desktop/icons/hicolor/48x48/apps/sun-java.png \
                 ${pkgdir}/usr/share/pixmaps/java.png

  rm -rf linux-jdk/jre
  mkdir -p ${pkgdir}/opt
  mv linux-jdk ${pkgdir}/opt/java

  install -D -m755 ${srcdir}/jdk.profile ${pkgdir}/etc/profile.d/jdk.sh

  mkdir -p ${pkgdir}/usr/share/licenses/jdk
  cp ${pkgdir}/opt/java/COPYRIGHT ${pkgdir}/usr/share/licenses/jdk
  cp ${pkgdir}/opt/java/LICENSE ${pkgdir}/usr/share/licenses/jdk
  cp ${pkgdir}/opt/java/THIRDPARTYLICENSEREADME.txt ${pkgdir}/usr/share/licenses/jdk
} 
