# Maintainer: Phillip Smith <fukawi2@archserver.org>
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Maintainer: Allan McRae <allan@archlinux.org>

# toolchain build order: kernel-headers->glibc->binutils->gcc-libs->gcc->binutils->glibc

pkgname=kernel-headers
pkgver=2.6.31.6
_BASEVER=2.6.31
pkgrel=2
pkgdesc="Kernel headers sanitized for use in userspace"
arch=('i686' 'x86_64')
license=('GPL')
url="http://www.gnu.org/software/libc"
groups=('core')
source=("ftp://ftp.kernel.org/pub/linux/kernel/v2.6/linux-$_BASEVER.tar.bz2"
        "http://www.kernel.org/pub/linux/kernel/v2.6/patch-$pkgver.bz2"
        scsi.patch)
md5sums=('84c077a37684e4cbfa67b18154390d8a'
         '89802830db41e517cdf0954145f73337'
         'b4b5d53506d704648816c70792cbf412')

build() {
  cd $srcdir/linux-$_BASEVER
  
  patch -Np1 -i $srcdir/patch-$pkgver || return 1
  
  # apply patch to fix issues with the scsi.h file (see #17).
  patch -Np1 -i $srcdir/scsi.patch || return 1
	
  make mrproper || return 1
  
  make headers_check || return 1
}

package() {
  cd $srcdir/linux-$_BASEVER
  
  make INSTALL_HDR_PATH="${pkgdir}/usr" headers_install || return 1
  
  rm -rf "${pkgdir}/usr/include/drm" || return 1
}

# vim:set ts=2 sw=2 et:
