# Maintainer: Douglas Soares de Andrade <douglas@archlinux.org>
# Maintainer: Phillip Smith <fukawi2@NOSPAM.gmail.com>

pkgname=postgresql
pkgver=8.4.2
pkgrel=1
pkgdesc="A sophisticated object-relational DBMS"
arch=(i686 x86_64)
groups=('lapp')
license=('BSD')
backup=('etc/conf.d/postgresql' 'etc/pam.d/postgresql')
url="http://www.postgresql.org/"
install="$pkgname.install"
options=('!makeflags')
provides=('postgresql-libs=8.4.1')
source=("ftp://ftp.postgresql.org/pub/source/v${pkgver}/postgresql-${pkgver}.tar.bz2" "rc.postgresql" "confd.postgresql")
md5sums=('d738227e2f1f742d2f2d4ab56496c5c6'
         '4ed9bb6ea489ef1c3859a093f1eba607'
         '09460fbfd3039bd9a0e753d5df360b5c')

# If changing this, update postgresql.install file too
_PKG_MAJOR_VER='8.4'

build() {
  cd $srcdir/$pkgname-$pkgver || return 1
  
  # build and install
  ./configure \
    --prefix=/usr \
    --with-system-tzdata=/usr/share/zoneinfo || return 1

  make || return 1
}

package() {
  cd $srcdir/$pkgname-$pkgver || return 1
  
  make DESTDIR=$pkgdir install || return 1
  
  # Install the adminpack contrib
  (
    cd contrib/adminpack || return 1;
    make || return 1;
    make DESTDIR=$pkgdir install || return 1;
  )
  
  # install rc script
  install -Dm755 $srcdir/rc.postgresql $pkgdir/etc/rc.d/postgresql || return 1
  
  # install conf file
  install -Dm644 $srcdir/confd.postgresql $pkgdir/etc/conf.d/postgresql || return 1
  
  # install license
  install -Dm644 $srcdir/$pkgname-$pkgver/COPYRIGHT $pkgdir/usr/share/licenses/$pkgname/LICENSE || return 1
}

# vim:set ts=2 sw=2 et:
