# Maintainer: Allan McRae <allan@archlinux.org>
# Contributer: Jason Chu <jason@archlinux.org>

pkgname=python
pkgver=2.6.3
pkgrel=2
_pybasever=2.6
pkgdesc="a high-level scripting language"
arch=('i686' 'x86_64')
license=('PSF')
url="http://www.python.org"
depends=('db>=4.8' 'bzip2' 'gdbm' 'openssl>=0.9.8d' 'zlib' 'expat' 'sqlite3>=3.6.15-2')
#makedepends=('tk>=8.5.0')
optdepends=('tk: for IDLE, pynche and modulator')
provides=('python2' 'python-elementtree' 'python-ctypes')
replaces=('python-elementtree' 'python-ctypes')
source=("http://www.python.org/ftp/python/${pkgver}/Python-${pkgver}.tar.bz2"
        'python-2.6-internal-expat.patch'
        'python-2.6-gdbm.patch'
        'python-2.6-readline.patch'
        'python-2.6-db-4.8.patch'
        'modulator-launcher'
        'pynche-launcher')
md5sums=('8755fc03075b1701ca3f13932e6ade9f'
         '993800dbcc0c4f199c1ceee998a06e71'
         '13fab4bb2cacbc433e62d7191a17f71e'
         '1f0aed8b96d4531f40fd3e24a80157a5'
         '10eb5449ead95b9cb13eae9f9a65894e'
         'b4a531570415280dc406c8d5c1fa8d83'
         '9f731b9033db285132a3524fb36409e7')

build() {
  cd $srcdir/Python-$pkgver
  
  patch -Np0 -i $srcdir/python-2.6-internal-expat.patch || return 1
  patch -Np1 -i $srcdir/python-2.6-gdbm.patch || return 1
  patch -Np0 -i $srcdir/python-2.6-readline.patch || return 1
  
  #http://bugs.python.org/issue6949
  patch -Np0 -i $srcdir/python-2.6-db-4.8.patch || return 1
  
  export OPT="${CFLAGS}"
  ./configure \
    --prefix=/usr \
    --enable-shared \
    --with-threads \
    --enable-unicode || return 1
  
  make || return 1
}

package() {
  cd $srcdir/Python-$pkgver
  
  make DESTDIR=$pkgdir install || return 1
  
  rm $pkgdir/usr/bin/python || return 1
  ln -sf python${_pybasever} ${pkgdir}/usr/bin/python || return 1
  ln -sf python${_pybasever} ${pkgdir}/usr/bin/python2 || return 1
  
  ln -sf ../../libpython${_pybasever}.so ${pkgdir}/usr/lib/python${_pybasever}/config/libpython${_pybasever}.so || return 1
  
  # Install the tools
  #modulator
  sed -i "s#%%PYBASEVER%%#${_pybasever}#" ${srcdir}/modulator-launcher || return 1
  install -m755 ${srcdir}/modulator-launcher ${pkgdir}/usr/bin/modulator || return 1
  cp -r Tools/modulator ${pkgdir}/usr/lib/python${_pybasever}/site-packages/ || return 1
  
  #pynche
  sed -i "s#%%PYBASEVER%%#${_pybasever}#" ${srcdir}/pynche-launcher || return 1
  install -m755 ${srcdir}/pynche-launcher ${pkgdir}/usr/bin/pynche || return 1
  rm -f Tools/pynche/*.pyw || return 1
  cp -r Tools/pynche ${pkgdir}/usr/lib/python${_pybasever}/site-packages/ || return 1
  
  #gettext
  install -m755 Tools/i18n/pygettext.py ${pkgdir}/usr/bin/ || return 1
  install -m755 Tools/i18n/msgfmt.py ${pkgdir}/usr/bin/ || return 1
  
  mkdir -p ${pkgdir}/usr/lib/python${_pybasever}/Tools/scripts || return 1
  install Tools/scripts/README ${pkgdir}/usr/lib/python${_pybasever}/Tools/scripts/ || return 1
  install Tools/scripts/*py ${pkgdir}/usr/lib/python${_pybasever}/Tools/scripts/ || return 1
  
  # license
  install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE || return 1
}

# vim:set ts=2 sw=2 et:
