# $Id: PKGBUILD 38557 2009-05-09 03:22:21Z eric $
# Maintainer: Eric Belanger <eric@archlinux.org>
# Contributor: Judd Vinet <jvinet@zeroflux.org>

pkgname=rsync
pkgver=3.0.7
pkgrel=1
pkgdesc="A file transfer program to keep remote files in sync"
arch=('i686' 'x86_64')
url="http://samba.anu.edu.au/rsync/"
license=('GPL3')
depends=('acl')
backup=('etc/rsyncd.conf' 'etc/xinetd.d/rsync')
source=("http://rsync.samba.org/ftp/rsync/src/${pkgname}-${pkgver}.tar.gz"
        "${pkgname}d.conf" "rc.${pkgname}d" "$pkgname.xinetd")
md5sums=('b53525900817cf1ba7ad3a516ab5bfe9'
         '4395c0591638349b1a7aeaaa4da1f03a'
         '9de4d03d49f4b5c73ffd67d452716a49'
         'ea3e9277dc908bc51f9eddc0f6b935c1')

build() {
  cd $srcdir/$pkgname-$pkgver
  
  ./prepare-source || return 1

  ./configure \
    --prefix=/usr \
    --with-included-popt \
    --enable-acl-support \
    --enable-xattr-support || return 1

  make || return 1
}

package() {
  cd $srcdir/$pkgname-$pkgver
  
  make DESTDIR=${pkgdir} install || return 1
  
  # install rc init script
  install -D -m 755 $srcdir/rc.rsyncd $pkgdir/etc/rc.d/rsyncd || return 1
  
  # install default conf file
  install -D -m 644 $srcdir/rsyncd.conf $pkgdir/etc/rsyncd.conf || return 1
  
  # install xinetd config template
  install -D -m 644 $srcdir/rsync.xinetd $pkgdir/etc/xinetd.d/rsync || return 1
}

# vim:set ts=2 sw=2 et:
